G-7150: Try to remove unused parameters.

Minor

Efficiency, Maintainability

Reason

You should go through your programs and remove any partameter that is no longer used.

Example (bad)

CREATE OR REPLACE PACKAGE BODY department_api IS
   FUNCTION name_by_id (in_department_id IN departments.department_id%TYPE
                       ,in_manager_id    IN departments.manager_id%TYPE)
      RETURN departments.department_name%TYPE IS
      l_department_name departments.department_name%TYPE;
   BEGIN
      <<find_department>>
      BEGIN
         SELECT department_name
           INTO l_department_name
           FROM departments
          WHERE department_id = in_department_id;
      EXCEPTION
         WHEN NO_DATA_FOUND OR TOO_MANY_ROWS THEN 
            l_department_name := NULL;
      END find_department;

      RETURN l_department_name;
   END name_by_id;
END department_api;
/

Example (good)

CREATE OR REPLACE PACKAGE BODY department_api IS
   FUNCTION name_by_id (in_department_id IN departments.department_id%TYPE)
      RETURN departments.department_name%TYPE IS
      l_department_name departments.department_name%TYPE;
   BEGIN
      <<find_department>>
      BEGIN
         SELECT department_name
           INTO l_department_name
           FROM departments
          WHERE department_id = in_department_id;
      EXCEPTION
         WHEN NO_DATA_FOUND OR TOO_MANY_ROWS THEN 
            l_department_name := NULL;
      END find_department;

      RETURN l_department_name;
   END name_by_id;
END department_api;
/